'---------------------------------------------------------
'Script para acesso ao Velox Versao 2.03 por Sergio Maluco
'---------------------------------------------------------
'Baseado no Script Versao 1.3 - By Ilanio Castro
'---------------------------------------------------------
'Exige Windows Scripting Host (WSH) instalado
'---------------------------------------------------------

Option Explicit
On Error Resume Next
Dim http, usr, pwd, prv, vlx, pin, pfi, ver, ten, pri
Err.Clear

'---------------------------------------------------------
'Inicio dos parametros de configuracao
'---------------------------------------------------------

'Nome de usuario no provedor (deixar vazio se Velox Empresarial)
usr = "eu"

'Senha de usuario no provedor
pwd = "123"

'Nome do Provedor (ver lista de nomes)
prv = "FACIL"

'Site do Velox
vlx = "www.veloxzone.com.br"

'Verificar conexão a cada 'ver' minutos (0 para conectar apenas uma vez)
ver = 10

'Tentar denovo em 'ten' minutos se não conseguir conectar (0 para sair) 
ten = 1

'Esperar 'pri' segundos para a primeira autenticacao (0 para nenhum)
pri = 0

'---------------------------------------------------------
'Termino dos parametros de configuracao
'---------------------------------------------------------
'Nao mexa em nada daqui em diante 
'---------------------------------------------------------
'A menos que saiba o que esta fazendo
'---------------------------------------------------------
'Qualquer problema remova o script e reinicie a maquina 
'---------------------------------------------------------

If Err <> 0 Then
	MsgBox "Erro definição dos parâmetros configuráveis." & Chr(10) & Chr(10) & "Por favor, verifique se você fechou todas as variáveis entre aspas e se as linhas não usadas estão devidamente comentadas com um apóstrofo.", 16, "Autenticação Velox:"
	WScript.Quit(0)
End If

If pri <> 0 Then
	WScript.Sleep 1000*pri
End If

pin = 0

Do While 1
	Err.Clear
	Set http = CreateObject("Microsoft.XmlHttp")
	If Err <> 0 Then
		MsgBox "Erro na criação do objeto de comunicação." & Chr(10) & Chr(10) & "Por favor, verifique.", 16, "Autenticação Velox:"
		WScript.Quit(0)
	End If
	
	Err.Clear
	http.Open "GET", "http://" & vlx & "/servlet/JavascriptProbe?prevURL=http://" & vlx & "/user/pages/serviceList.jsp&browser=explorer&version=6&javascript=1.3&getElementById=true&getElementTagName=true&documentElement=true&anchors=true&regexp=true&option=true&all=true&cookie=true&images=true&layers=false&forms=true&links=true&frames=true&screen=true", FALSE
	http.Send ""
	
	if pin = 0 Then
		If Err <> 0 Then
			MsgBox "Erro na comunicação com o site do Velox." & Chr(10) & Chr(10) & "Por favor, verifique se sua conexão é válida.", 16, "Autenticação Velox:"
			Set http = nothing
			WScript.Quit(0)
		End If

		Err.Clear
		pin = InStr(1, http.ResponseText, "internet_", 1)
		pfi = InStr(pin, http.ResponseText, prv, 1)
		pin = InStrRev(http.ResponseText, "internet_", pfi, 1)
		pfi = InStr(pin, http.ResponseText,"'", 1)
		prv = Mid(http.ResponseText, pin, pfi - pin)
		If Err <> 0 Then
			MsgBox "Erro no tratamento das informações obtidas do site do Velox." & Chr(10) & Chr(10) & "Por favor, verifique se seu script ainda é válido.", 16, "Autenticação Velox:"
			Set http = nothing
			WScript.Quit(0)
		End If
	End If

	If InStr(1, http.responsetext, "serviceStop?", 1) > 0 Then
		Set http = nothing
		If ver <> 0 Then
			WScript.Sleep 60000*ver
		Else
			MsgBox "A sua conexão já se encontra estabelecida.", 64, "Autenticação Velox:"
			WScript.Quit(0)
		End If
	Else
		Err.Clear
		If Len(usr) > 0 Then
			http.Open "POST", "http://" & vlx & "/serviceLogon?service=" & prv, FALSE
			http.SetRequestHeader "Content-Type","application/x-www-form-urlencoded"
			http.Send "service=" & prv & "&fcn=serviceLogon&ac=home&username=" & usr & "&password=" & pwd
		Else
			http.Open "POST", "http://" & vlx & "/serviceStart?service=" & prv, FALSE
			http.SetRequestHeader "Content-Type","application/x-www-form-urlencoded"
			http.Send "service=" & prv & "&confirmed=true"
		End If
		If Err <> 0 Then
			Set http = nothing
			If ten <> 0 Then
	  			WScript.Sleep 60000*ten
			Else
				MsgBox "Erro no envio da solicitação de autenticação ao site do Velox." & Chr(10) & Chr(10) & "Por favor, verifique se seu script ainda é válido.", 16, "Autenticação Velox:"
				WScript.Quit(0)
			End If
		Else
			Set http = nothing
			If ver <> 0 Then
				WScript.Sleep 60000*ver
			Else
				MsgBox "Autenticação no Velox realizada com sucesso.", 64, "Autenticação Velox:"
				WScript.Quit(0)
			End If

		End If
	End If
Loop